使用SQL SERVER存儲過程實現歷史數據遷移方式

USE [Tyingsoft.GLPS]
GO
/****** Object:  StoredProcedure [dbo].[TY_SP_ApiRequestToHis]    Script Date: 2021-09-16 15:35:55 ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
-- =============================================
-- Author:
-- Create date:
-- Last Edit date:
-- Description:    <接口請求記錄表GLPS_APIREQUEST數據遷移>
-- =============================================
ALTER PROCEDURE [dbo].[TY_SP_ApiRequestToHis]
    -- Add the parameters for the stored procedure here
    @PreCountN int = 2000     --每次執行的條數N
AS
BEGIN
    -- SET NOCOUNT ON added to prevent extra result sets from
    -- interfering with SELECT statements.
    SET NOCOUNT ON;

    declare @tableDataCount int;          --遷移前的數據條數
    declare @tableDataCountHis int;       --遷移前歷史數據庫的數據條數
    declare @tableDataCount2 int;         --遷移後的數據條數
    declare @tableDataCount2His int;      --遷移後歷史數據庫的數據條數
    declare @maxCreateTime datetime;      --取N條數據中最大的創建時間
    declare @maxCreateTimeHis datetime;   --歷史數據庫中的最大創建時間
    declare @beginTime datetime;          --開始執行時間
    declare @endTime datetime;            --執行完成時間
    declare @execTimeMS int;              --執行時間（毫秒數）

    --中間步驟debugger耗時使用
    declare @tmpBeginTime datetime;       --(臨時)開始執行時間
    declare @tmpEndTime datetime;         --(臨時)執行完成時間
    declare @tmpExecTimeMS int;           --(臨時)執行時間（毫秒數）

    select @beginTime = getdate();

    --遷移前：先查詢數據條數
    select @tableDataCount = count(1) from [Tyingsoft.GLPS].dbo.GLPS_APIREQUEST;
    select @tableDataCountHis =count(1) from  [Tyingsoft.GLPS_His].dbo.GLPS_APIREQUEST;

    print '【接口請求記錄表（GLPS_APIREQUEST）數據遷移】開始執行時間：' + convert(nvarchar(50),@beginTime,20);
    print '本次計劃遷移數據條數：'+ cast( @PreCountN as nvarchar(20));

    --創建一個臨時公用表達式 （表中最早創建的N條數據）
    with topNRecord (FCREATETIME)
    as
    (
        select top (@PreCountN) FCREATETIME from GLPS_APIREQUEST  order by FCREATETIME
    )

    --取N條數據中最大的創建時間
    select @maxCreateTime =max(FCREATETIME) from topNRecord

    print '對應遷移數據FCREATETIME為：'+ convert(nvarchar(50),@maxCreateTime,21); --日期轉化為字符串格式：yyyy-MM-dd HH:mm:ss.fff


    select @tmpBeginTime = GETDATE();  --中間步驟開始計時

    --第一步：將N條數數據寫入到歷史數據庫
    insert into [Tyingsoft.GLPS_His].dbo.GLPS_APIREQUEST
    select * from [Tyingsoft.GLPS].dbo.GLPS_APIREQUEST  where  FCREATETIME <=@maxCreateTime

    select @tmpEndTime = GETDATE();   --中間步驟計時結束
    print '數據遷移，插入耗時（毫秒）：' +cast( datediff(millisecond,@tmpBeginTime,@tmpEndTime) as nvarchar(20));


    --第二步：對比歷史數據庫的數據
    select @maxCreateTimeHis=max(FCREATETIME) from [Tyingsoft.GLPS_His].dbo.GLPS_APIREQUEST

    if @maxCreateTime = @maxCreateTimeHis
       begin
            select @tmpBeginTime = GETDATE();  --中間步驟開始計時

            --第三步：執行完以後，再刪除數據
            delete from GLPS_APIREQUEST where FCREATETIME <=@maxCreateTime
            print '遷移後刪除數據條數：' + cast( @@ROWCOUNT as nvarchar(50));

            select @tmpEndTime = GETDATE();       --中間步驟計時結束
            print '數據遷移，刪除耗時（毫秒）：' +cast( datediff(millisecond,@tmpBeginTime,@tmpEndTime) as nvarchar(20));
        end
    else
        print '遷移後，日期校驗錯誤，未刪除數據！！！'

    --遷移後：再查詢數據條數
    select @tableDataCount2 = count(1) from [Tyingsoft.GLPS].dbo.GLPS_APIREQUEST;
    select @tableDataCount2His =count(1) from  [Tyingsoft.GLPS_His].dbo.GLPS_APIREQUEST;

    print '遷移前GLPS_APIREQUEST的數據條數：' + cast(@tableDataCount as nvarchar(20))
     + ',遷移後數據條數：'+cast(@tableDataCount2 as nvarchar(20))
     + ',差額：'+cast((@tableDataCount2-@tableDataCount) as nvarchar(20));

    print '遷移前His.GLPS_APIREQUEST的數據條數：'
    + cast(@tableDataCountHis as nvarchar(20))
    +',遷移後數據條數：'+cast(@tableDataCount2His as nvarchar(20))
    + ',差額：'+cast((@tableDataCount2His-@tableDataCountHis) as nvarchar(20));

    print '註意：正式環境一直有數據變動，所以會有一定的偏差！';


    select @endTime = GETDATE();
    print '總耗時（毫秒）：' +cast( datediff(millisecond,@beginTime,@endTime) as nvarchar(20));


END