Unity Shader實現3D翻頁效果

Shader "Unlit/PaperTurnMilkShader"
{
 Properties
 {
  //正面圖
  _MainTex ("Texture", 2D) = "white" {}
  //背面圖
  _SrcTex("SrcTex", 2D) = "white"{}
  //旋轉角度
  _Angle("Angle", Range(0,180)) = 0
  //彎曲程度
  _WeightY("Weight Y", Range(0,3)) = 0.2
  //收縮程度（值越大翻頁時紙張越往內部靠攏)具體情況可測試
  _WeightX("Weight X", Range(0,1)) = 0
  //波長（值越大翻頁時的彎曲次數越多）
  _WaveLength("WaveLength", Range(0,2)) = 0.4
 }
 SubShader
 {
  //關閉批處理（因為修改瞭頂點位置)
  Tags { "RenderType"="Opaque" "IgnoreProjector" = "True" "Queue" = "Geometry" "DisableBatching" = "True"}
  LOD 100
  //渲染正面
  Pass
  {
   Cull Back
   CGPROGRAM
   #pragma vertex vert
   #pragma fragment frag   
   
   #include "UnityCG.cginc"
 
   struct appdata
   {
    float4 vertex : POSITION;
    float2 uv : TEXCOORD0;
   };
 
   struct v2f
   {
    float2 uv : TEXCOORD0;    
    float4 vertex : SV_POSITION;
   };
 
   sampler2D _MainTex;
   float4 _MainTex_ST;
   float _Angle;
   float _WeightY;
   float _WeightX;
   float _WaveLength;
   
   v2f vert (appdata v)
   {
    v2f o;
    //對頂點進行往X正方向偏移5個單位是為瞭離開旋轉中心點,不然翻頁時的旋轉點是會在紙張中心進行圍繞Z軸旋轉（Z軸是紙張垂直線）
    v.vertex += float4(5, 0, 0, 0);
    float s;
    float c;
    //使用sincos獲取 sin(弧度), cos(弧度)  ，radians(角度)=弧度 ,_Angle前加負號是控制旋轉方向，可根據DX是右手法則順時針旋轉，故應該逆向翻頁要取負數
    sincos(radians(-_Angle), s, c);
    //圍繞Z軸旋轉變換矩陣
    float4x4 rotate = {
     c,s,0,0,
     -s,c,0,0,
     0,0,1,0,
     0,0,0,1
    };
    //weight：_Angle在[0,90]變換區間時，weight會從0變為1；_Angle在[90,180]變換區間時，weight會從1變為0. 
    //weight可理解為是剛開始翻頁（0°）到翻頁到垂直時（90°）時，對其彎曲程度從小變大；（這個是對頂點Y值影響的結果）
    //同理，收縮程度也是一樣道理
    float weight = 1 - abs(90 - _Angle) / 90;
    v.vertex.y += sin(v.vertex.x * _WaveLength) * weight * _WeightY;
    v.vertex.x -= v.vertex.x * weight * _WeightX;
    //在進行偏移之後，再對頂點進行圍繞Z軸旋轉_Angle角度
    v.vertex = mul(rotate, v.vertex);
 
    //之後要偏移回來，因為我們已經做完瞭上面的旋轉操作瞭
    v.vertex -= float4(5, 0, 0, 0);
    o.vertex = UnityObjectToClipPos(v.vertex);
    o.uv = TRANSFORM_TEX(v.uv, _MainTex);    
    return o;
   }
   
   fixed4 frag (v2f i) : SV_Target
   {    
    fixed4 col = tex2D(_MainTex, i.uv);    
    return col;
   }
   ENDCG
  }
 
  //渲染背面(和上方渲染正面PASS唯一的差別是：片元著色器的采樣紋理改為_SrcTex(背面圖）
  Pass
  {
   Cull Front
   CGPROGRAM
   #pragma vertex vert
   #pragma fragment frag   
 
   #include "UnityCG.cginc"
 
   struct appdata
   {
    float4 vertex : POSITION;
    float2 uv : TEXCOORD0;
   };
 
   struct v2f
   {
    float2 uv : TEXCOORD0;
    float4 vertex : SV_POSITION;
   };
 
   sampler2D _SrcTex;
   float4 _MainTex_ST;
   float _Angle;
   float _WeightY;
   float _WeightX;
   float _WaveLength;
   v2f vert(appdata v)
   {
    v2f o;
    v.vertex += float4(5, 0, 0, 0);
    float s;
    float c;
    //使用sincos獲取 sin(弧度), cos(弧度)  ，radians(角度)=弧度
    sincos(radians(-_Angle), s, c);
    //圍繞Z軸旋轉變換矩陣
    float4x4 rotate = {
     c,s,0,0,
     -s,c,0,0,
     0,0,1,0,
     0,0,0,1
    };
    float weight = 1 - abs(90 - _Angle) / 90;
    v.vertex.y += sin(v.vertex.x * _WaveLength) * weight * _WeightY;
    v.vertex.x -= v.vertex.x * weight * _WeightX;
    v.vertex = mul(rotate, v.vertex);
 
    v.vertex -= float4(5, 0, 0, 0);
 
    o.vertex = UnityObjectToClipPos(v.vertex);
    o.uv = TRANSFORM_TEX(v.uv, _MainTex);
    return o;
   }
 
   fixed4 frag(v2f i) : SV_Target
   {
    fixed4 col = tex2D(_SrcTex, i.uv);
    return col;
   }
   ENDCG
  }
 }
}