批處理位運算演示代碼

@echo off
title 位運算示例   code by:cn-bathome-more
echo.
echo.位運算名詞解釋(個人理解):
echo.
echo.位運算: 按操作數在計算機內表示的二進制數逐位進行邏輯運算或移位運算.
echo.與:   全部都是1才為1(指返回值,下同),否則為0.
echo.或:   隻要有1則為1,否則為0.
echo.異或: 不同為1,相同為0.
echo.取反: 是1則0,是0則1(單目運算符).
echo.取負: 先取反再加1(單目運算符).
echo.左移n位: 相當於乘以2的n次方(用0補位).
echo.右移n位: 相當於除以2的n次方(負數用1補位,正數用0補位).
echo.
echo.下面的示例是在三十二位系統(數值范圍:-2147483648~2147483647)下運行的結果.
echo.請輸入批處理能處理的數值(整數),否則將不能正確處理.如發生溢出,結果也不會正確.
echo.
rem 將十進制轉換為二進制的函數.
set "fun_d2b=setlocal enabledelayedexpansion&(for /l %%a in (0 1 31) do (set /a "str=!#a#!^>^>%%a"&set /a "str^&=1"&set "str_d2b=!str!!str_d2b!"))&(for %%a in (!str_d2b!) do (endlocal&set #a#=%%a))"
setlocal enabledelayedexpansion
:agn
set in=&set /p in=請輸入兩個數(中間用空格隔開):
if not defined in exit
set n=0
for %%a in (%in%) do (
   set /a n+=1
   set /a num!n!=%%a 2>nul
)
cls
echo.輸入的兩個數的有效數值為: "!num1!" 和 "!num2!", 用二進制表示分別為:
set /a str1=num1,str2=num2
%fun_d2b:#a#=str1%
%fun_d2b:#a#=str2%
echo.&echo.!str1!  ==^> !num1!
echo.!str2!  ==^> !num2!
echo.&echo.各種位運算的結果如下:
set /a "num=!num1!&!num2!,t=num"
%fun_d2b:#a#=num%&echo.&echo.!num! ==^> 按位與:   !num1! ^& !num2! = !t!
set /a "num=!num1!|!num2!,t=num"
%fun_d2b:#a#=num%&echo.&echo.!num! ==^> 按位或:   !num1! ^| !num2! = !t!
set /a "num=!num1!^^!num2!,t=num"
%fun_d2b:#a#=num%&echo.&echo.!num! ==^> 按位異或: !num1! ^^^^ !num2! = !t!
set /a "num=~!num1!,t=num"
%fun_d2b:#a#=num%&echo.&echo.!num! ==^> 按位取反:    ~(!num1!) = !t!
set /a "num=-!num1!,t=num"
%fun_d2b:#a#=num%&echo.&echo.!num! ==^> 取負:        -(!num1!) = !t!
set /a "ran=%random%%%5+2,num=!num1!,num<<=ran,t=num"
%fun_d2b:#a#=num%&echo.&echo.!num! ==^> 左移!ran!位:   !num1! ^<^< !ran! = !t!
set /a "ran=%random%%%5+2,num=!num1!,num>>=ran,t=num"
%fun_d2b:#a#=num%&echo.&echo.!num! ==^> 右移!ran!位:   !num1! ^>^> !ran! = !t!
echo.&goto :agn

@echo off
::定義函數
set "d-h=setlocal enabledelayedexpansion&set/a dx=#a#&set xs=0123456789abcdef&(for /l %%z in (1,1,4) do set /a x%%z=dx%%16,dx=dx/16)&(for /f "tokens=1-4" %%1 in ("!x1! !x2! !x3! !x4!") do set hx=!xs:~%%4,1!!xs:~%%3,1!&(if !hx!==00 set hx=)&(for %%z in ("!hx!!xs:~%%2,1!!xs:~%%1,1!") do endlocal&set #a#=%%~z))"
::10進制轉為16進制的函數,參數入口#a#
::要在開啟變量延遲之前定義
setlocal enabledelayedexpansion
for /l %%a in (1,7,1024) do (
    set abc=%%a
    
(%d-h:#a#=abc%)
rem 函數調用

echo !abc!
)
pause

@echo off

::定義函數
set "d-h=setlocal enabledelayedexpansion&set/a dx=#a#&set xs=0123456789abcdef&(for /l %%z in (1,1,4) do set /a x%%z=dx%%16,dx=dx/16)&(for /f "tokens=1-4" %%1 in ("!x1! !x2! !x3! !x4!") do set hx=!xs:~%%4,1!!xs:~%%3,1!&(if !hx!==00 set hx=)&(for %%z in ("!hx!!xs:~%%2,1!!xs:~%%1,1!") do endlocal&set #a#=%%~z))"
::10進制轉為16進制的函數,調用方法：%d-h:#a#=變量名%

set "len=for /f "tokens=1-3" %%1 in ("#a#") do setlocal enabledelayedexpansion&(if defined %%2 (set /a z=8180,x=0&(for /l %%a in (1,1,14) do set/a "y=(z-x)/2+x"&(for %%b in (!y!) do if "!%%2:~%%b,1!" equ "" (set/a z=y) else (set/a x=y)))) else (set z=0))&(for %%z in ("!z!") do endlocal&set %%1=%%~z)"
::取字符串長度函數，調用方法：%len:#a#=結果變量名 字符串變量名%
setlocal enabledelayedexpansion

for /l %%a in (1,7,1024) do (
    set abc=%%a

        (%len:#a#=slen abc%)
        (%d-h:#a#=abc%)
        (%len:#a#=dlen abc%)
        rem 函數調用
        
        echo %%a轉成16進制為：!abc!   轉換前字符數:!slen!  轉換後字符數:!dlen!
)
pause