Unity基於ShaderLab實現光照系統(著色器代碼實現小結)

Posted on by

這篇主要總結Unity中ShaderLab的著色器代碼實現總結，需要有一定圖形學基礎和ShaderLab基礎；

一、著色器

1.頂點片元著色器

分頂點著色器和片元著色器，對應渲染管線的頂點變換和片元著色階段；

最簡單的頂點片元著色器：

Shader "MyShader/VertexFragmentShader"
{
    Properties{
        _MainColor("MainColor",Color) = (1,1,1,1)
    }
        SubShader
    {
        Tags { "RenderType" = "Opaque" }
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            float4 _MainColor;
            float4 vert(float4 v:POSITION) :SV_POSITION
            {
                return UnityObjectToClipPos(v);
            }
            fixed4 frag () : SV_Target
            {        
                return _MainColor;
            }
            ENDCG
        }
    }
}

2.表面著色器

將頂點和片元著色器再進行一層封裝；

通過表面函數控制反射率，光滑度，透明度等；

通過光照函數選擇要使用的光照模型；

表面著色器提供瞭便利，但是也降低瞭自由度；

表面著色器能實現的，頂點片元著色器都可以實現，但頂點片元著色器的可操作性更高，性能也更好；

簡單的表面著色器：

Shader "MyShader/SurfaceShader"
{
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        CGPROGRAM
        //表面著色器,使用Lambert光照
        #pragma surface surf Lambert 
           
        struct Input {
        float4 color :COLOR;
        };
        
        void surf(Input IN,inout SurfaceOutput o) {
            o.Albedo = 1;
        }
       
        ENDCG
    }
    Fallback "Diffuse"
}

3.固定函數著色器

已基本棄用不分析瞭；

二、光照模型

1.逐頂點光照(Gourand Shading)

在頂點著色器計算光照；頂點數目比片元少，計算量也少，通過線性插值得到每個像素的光照；

所以非線性光照計算時會出錯——高光（後面會寫）；

v2f vert(a2v v) {
	v2f o;
	//頂點變換到裁剪空間
	o.pos = UnityObjectToClipPos(v.vertex); 
    
	//環境光
	fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
    
	//世界空間下法線
	fixed3 worldNormal = normalize(mul(v.normal,unity_WorldToObject));
    
	//世界空間下光照方向
	fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
    
	//點成光照和法線得出漫反射方向，satruate取區間0-1;
	fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));
    
	//環境光+漫反射
	o.color = ambient + diffuse;
	return o;
}

2.逐片元光照(Phong Shading)

在片元著色器計算光照；根據每個片元的法線計算光照；效果好計算量大，也叫phong插值；

v2f vert(a2v v) {
	v2f o;
	//頂點變換到裁剪空間
	o.pos = UnityObjectToClipPos(v.vertex);

	//傳遞世界坐標法線到片元著色器
	o.worldNormal = mul(v.normal,unity_WorldToObject);
	
	return o;
}

fixed4 frag(v2f v) :SV_Target{
	//環境光
	fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
	
	//歸一化世界法線
	fixed3 worldNormal = normalize(v.worldNormal);

	//歸一化世界空間下光照方向
	fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
	
	//求漫反射
	fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));
	
	//相加環境光和漫反射
	fixed3 color = ambient + diffuse;
	return fixed4(color,1.0);
}

這也是Lambert光照模型的算法；

3.HalfLambert 光照

v社做半條命使用一個標準，計算漫反射時候結果+0,5；這樣對暗部有很大的優化；

//HalfLambertParma
fixed halfLambert = dot(worldNormal, worldLight) * 0.5 + 0.5;

//使用halfLambert計算漫反射
fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * halfLambert;

4.逐頂點高光

上面說的逐頂點計算光照對非線性光照會有錯誤；

高光由反射導致，和觀察方向、光線方向有關；具體關系參考圖形學基礎；

在頂點著色器函數中添加：

//根據法線和光線方向用reflect方法計算反射方向
fixed3 reflectDir = normalize(reflect(-worldLight, worldNormal));

//計算觀察方向，攝像機位置-頂點位置（要求同在世界坐標系下）
fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, v.vertex).xyz);

//Phong光照模型中高光計算公式，_Specular顏色，_Gloss粗糙度，_LightColor0系統參數光照顏色
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);

o.color = ambient + diffuse + specular;

5.逐像素高光

將逐頂點高光代碼發放在片元著色器中執行；

6.Bline-Phong光照模型

上面逐頂點和逐像素高光都是使用Phong光照模型；

求高光的時候使用reflect函數計算反射向量，計算比較大；

Bline-Phong使用（光線方向+觀察方向）來替代反射向量；

//世界光線方向和觀察方向中間方向;
fixed3 halfDir = normalize(worldLight + viewDir);

//使用halfDir來計算高光
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);

fixed3 color = ambient + diffuse + specular;

三、紋理貼圖

1.單張紋理

使用紋理取樣替代純色，在片元著色器中對紋理貼圖取樣，修改像素顏色；

_MainTexture_ST 控制貼圖的縮放和偏移（Scale,Translate）;

v2f vert(a2v v){
	//uv傳遞給片元著色器,可以使用宏命令TRANSFORM_TEX
	o.uv = v.texcoord.xy * _MainTexture_ST.xy + _MainTexture_ST.zw;
	//o.uv = TRANSFORM_TEX(v.texcoord,_Maintexture);
}
fixed4 farg(v2f v) :SV_Target{
    //紋理取樣,表面顏色-紋素
	fixed3 albedo = tex2D(_MainTexture, v.uv).rgb * _Color.rgb;
	//環境光*表面顏色
	fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz *albedo;
					
	fixed halfLambert = dot(worldNormal, worldLight) * 0.5 + 0.5;
	//漫反射*表面顏色
	fixed3 diffuse = _LightColor0.rgb * albedo.rgb * halfLambert;
}

2.法線紋理

法線計算兩種方式：

將光線和觀察向量變換到切線空間計算；

將切線空間下法線變換到世界空間計算；

切線空間計算由於矩陣變換在頂點著色器，計算少效率高；

由於認知，或者有其他需求我們也會在世界空間計算法線；

– 法線紋理切線空間計算

v2f vert(a2v v) {
	v2f o;
	o.pos = UnityObjectToClipPos(v.vertex);

	o.uv.xy = v.texcoord.xy * _MainTexture_ST.xy + _MainTexture_ST.zw;
	//o.uv = TRANSFORM_TEX(v.texcoord,_Maintexture);
	o.uv.zw = TRANSFORM_TEX(v.texcoord,_BumpMap);

	//宏定義,求世界空間——切線空間變換矩陣rotation
	TANGENT_SPACE_ROTATION;
	
	o.lightDir = mul(rotation,ObjSpaceLightDir(v.vertex)).xyz;
	o.viewDir = mul(rotation,ObjSpaceViewDir(v.vertex)).xyz;

	return o;
}

fixed4 frag(v2f v) :SV_Target{
	//切線空間-光線方向
	fixed3 tangentLightDir = normalize(v.lightDir);
   
	//切線空間-觀察方向
    fixed3 tangentViewDir = normalize(v.viewDir);
		
	//法線貼圖格式為NormalMap,使用UnpackNormal解壓,取樣得到切線空間下法線
	fixed3 tangentNormal = UnpackNormal(tex2D(_BumpMap,v.uv.zw));
	//法線縮放
	tangentNormal.xy *= _BumpScale;
	//法線貼圖壓縮方法,z值可以計算得出,勾股定理,以下是簡化後公式
	tangentNormal.z = sqrt(1.0-saturate(dot(tangentNormal.xy,tangentNormal.xy)));
	
    ...//漫反射高光計算都使用tangentNormal
}

– 法線紋理世界空間計算

v2f vert(a2v v) {
	v2f o;
	o.pos = UnityObjectToClipPos(v.vertex);
	//減少寄存器使用,xy記錄主紋理uv,zw記錄法線uv
	o.uv.xy = v.texcoord.xy * _MainTexture_ST.xy + _MainTexture_ST.zw;
	o.uv.zw = TRANSFORM_TEX(v.texcoord,_BumpMap);
	//求世界空間下法線、切線、副切線
	float3 worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
	fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
	fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
	fixed3 worldBinnormal = cross(worldNormal,worldTangent)*v.tangent.w;
	
	//法線、切線、副切線構成切線空間變換矩陣,w值trick利用存儲世界坐標系頂點坐標
	o.Ttow0 = float4(worldTangent.x,worldBinnormal.x,worldNormal.x,worldPos.x);	
	o.Ttow1 = float4(worldTangent.y,worldBinnormal.y,worldNormal.y,worldPos.y);	
	o.Ttow2 = float4(worldTangent.z,worldBinnormal.z,worldNormal.z,worldPos.z);	
	return o;
}
fixed4 frag(v2f v) :SV_Target{
    ...
        
    //法線貼圖格式為NormalMap,使用UnpackNormal解壓,取樣得到切線空間法線
	fixed3 tangentNormal = UnpackNormal( tex2D(_BumpMap,v.uv.zw));
	
    //法線縮放
	tangentNormal.xy *= _BumpScale;
	
    //法線貼圖壓縮方法,z值可以計算得出,勾股定理,以下是簡化後公式
	tangentNormal.z = sqrt(1.0-saturate(dot(tangentNormal.xy,tangentNormal.xy)));
	
    //矩陣變換求出世界空間法線
	tangentNormal = normalize(half3(dot(v.Ttow0.xyz,tangentNormal),dot(v.Ttow1.xyz,tangentNormal),dot(v.Ttow2.xyz,tangentNormal)));
	
    ...//漫反射高光計算都使用tangentNormal
}

3.漸變紋理

以上漫反射顏色都是光線顏色，或者光線顏色混合表面紋素顏色；

有時候漫反射的顏色要根據反射角大小有不同的變化，比如卡通渲染；

這就需要使用漸變紋理RampTexture；

//頂點著色器轉化RampTex的uv
 fixed4 frag (v2f i) : SV_Target{
    fixed halfLambert = 0.5 * dot(worldNormal,worldLightDir)+0.5;
    
     //根據halfLambert反射方向取樣RampTex紋素
	fixed3 diffuseColor = tex2D(_RampTex, fixed2(halfLambert, 			halfLambert)).rgb*_Color.rgb;

	fixed3 diffuse = _LightColor0.rgb * diffuseColor;
 }

三種不同的Ramp紋理：

4.遮罩紋理

有些部位高光效果太強，人為的希望有些部位暗一些等，可以用到遮罩紋理Mask；

片元著色器中添加：

//反射方向
fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);

//uv取樣高光遮罩紋理*高光范圍
fixed3 specularMask = tex2D(_SpecularMask,i.uv).r *_SpecularScale;

//高光結果混合遮罩紋理
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(tangentNormal,halfDir)),_Gloss) * specularMask;

效果對比：

四、透明物體

1.透明測試

AlphaTest隻決定畫不畫，不做顏色混合，給定一個閾值_Cutoff，透明度小於這個值都不畫；

透明測試需要關閉背面裁剪，以及加上透明測試三套件；

Tags { "Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="Transparent"}

//渲染隊列,忽略投影器,渲染類型
Tags { "Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="Transparent"}
        
//關閉裁剪
Cull Off

Pass{
	...
	  fixed4 frag (v2f i) : SV_Target{
	  		...
	  		//alpha值小於_Cutoff的都不畫
            clip(texColor.a - _Cutoff);
	  		...
	  }
	...
}

修改Culloff值大小的效果：

2.透明顏色混合

AlphaBlend透明混合要關閉深度寫入，否則會被剔除；

同時要選擇混合模式，多種混合模式有點像ps裡的透明圖層疊加；

//三套件
Tags { "Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
      
Pass{
	//關閉深度吸入,打開深度測試,選擇顏色混合模式
	Tags{"LightMode"="ForwardBase"}
    ZWrite Off
    Blend SrcAlpha OneMinusSrcAlpha 
    
    ...
    
    fixed4 frag (v2f i) : SV_Target{
    	...
     	//返回著色是,加上透明度
        return fixed4(ambient +diffuse,texColor.a*_AlphaScale);
    }    
}

3.復雜模型雙Pass顏色混合

模型復雜的時候會有自己遮擋自己的問題；用雙Pass解決，第一個pass提前做好深度寫入且隻做深度入；

Pass{
    ZWrite On
    ColorMask 0     //RGBA任意|,選擇需要寫入的通道,隻做深度緩沖,0不輸出顏色
}

4.透明混合渲染雙面

同一個透明物體，我需要需要從正面看到透明物體的背面；

使用兩個Pass；一個Cull Front，一個Cull Back；

背面和正面分開畫，先畫背面，用正面和背面混合；

五、復雜光照處理

1.復雜光照

Unity光源分為垂直光，點光源，錐形射光燈，面光源和探照燈都是烘焙後生效的不討論；

Unity中普通Forwad前向渲染，沒多一個燈光要加一個Pass單獨處理；

Deffer延遲渲染，多個燈光也指渲染一次，有個G-Buffer存儲瞭圖像，在G-Buffer上處理光照；

點光源，錐形射光燈——光線方向由光源到頂點的方向；光線的衰減值也不同；

Unity系統提供的點光源和錐形射光燈的光線衰減紋理圖，減少瞭計算；

Tags{"LightMode" = "ForwardAdd"}
#pragma multi_compile_fwdadd

#include "Lighting.cginc"
#include "AutoLight.cginc"

fixed4 frag (v2f i) : SV_Target
{            
    fixed3 worldNormal = normalize(i.worldNormal);              
    
    //deal with different light,get worldLightDir;
    #ifdef USING_DIRECTIONAL_LIGHT
        fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
        fixed atten = 1.0;
    #else
        fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz - i.worldPos.xyz);  
        
    	//Get light attenuation
        #if defined (POINT)
	        float3 lightCoord = mul(unity_WorldToLight, float4(i.worldPos, 1)).xyz;
	        fixed atten = tex2D(_LightTexture0, dot(lightCoord, lightCoord).rr).UNITY_ATTEN_CHANNEL;
	    #elif defined (SPOT)
	        float4 lightCoord = mul(unity_WorldToLight, float4(i.worldPos, 1));
	        fixed atten = (lightCoord.z > 0) * tex2D(_LightTexture0, lightCoord.xy / lightCoord.w + 0.5).w * tex2D(_LightTextureB0, dot(lightCoord, lightCoord).rr).UNITY_ATTEN_CHANNEL;
	    #else
	        fixed atten = 1.0;
	    #endif
    #endif
	
    ...
	
    return fixed4((diffuse+specular)*atten,1.0);
}

2.陰影處理

Untiy中MeshRender組件上有兩個選項：

CastShadows——是否投射陰影，以及雙面投射；

Receive Shadows——接受其他物體投射的陰影；

要求v2f中頂點坐標變量名必須是pos；

帶陰影的shader必須FallBack一個帶LightMode被設置為ShadowCaster的pass；

當然也可以自己實現這個Pass；

Tags { "LightMode"="ForwardBase" }

CGPROGRAM
#pragma multi_compile_fwdbase

#include "Lighting.cginc"
#include "AutoLight.cginc"

struct v2f
{
    float4 pos : SV_POSITION;
    SHADOW_COORDS(2)
};

v2f vert (appdata v)
{
    v2f o;
    o.pos = UnityObjectToClipPos(v.vertex);

    TRANSFER_SHADOW(o);
    return o;
}


fixed4 frag (v2f i) : SV_Target
{
	fixed atten = 1.0;
	fixed shadow = SHADOW_ATTENUATION(i);
	return fixed4((ambient+ diffuse + specular)*atten*shadow,1.0);
}

3.透明物體陰影處理

CastShadows——改成Two Sides即可；

Life is too short for so much sorrow.

到此這篇關於Unity基於ShaderLab實現光照系統的文章就介紹到這瞭,更多相關Unity光照系統內容請搜索WalkonNet以前的文章或繼續瀏覽下面的相關文章希望大傢以後多多支持WalkonNet！

推薦閱讀：